! From Mick Spillane spillane@pmel.noaa.gov

! plot i[i=1:100]
! go likealine 0 100 0 100
!
! use monthly_navy_winds
! plot uwnd[i=@ave,j=@ave]
! go likealine 0 100 0 100 uwnd

!-----------------------------------
! Relative to bug err551_XAXIS_1.jnl
def sym ME_XAXIS_VAR=$5%XXXXX%

if ($ME_XAXIS_VAR%|XXXXX>true|*>false|%) then
        def sym ME_XAXIS_MIN=($XAXIS_MIN)
        def sym ME_XAXIS_MAX=($XAXIS_MAX)
else
        let ME_XAXIS_VAR_T=t[gt=($ME_XAXIS_VAR)]
        def sym ME_XAXIS_MIN=`ME_XAXIS_VAR_T[l=1]`
        def sym ME_XAXIS_LEND=`ME_XAXIS_VAR_T,return=lend`
        def sym ME_XAXIS_MAX=`ME_XAXIS_VAR_T[l=($ME_XAXIS_LEND)]`
endif
!-----------------------------------

let x1=`($VP_WIDTH) * ($1)/100 - ($PPL$XORG)`
let x2=`($VP_WIDTH) * ($2)/100 - ($PPL$XORG)`
let y1=`($VP_HEIGHT) * ($3)/100 - ($PPL$YORG)`
let y2=`($VP_HEIGHT) * ($4)/100 - ($PPL$YORG)`

ppl window,off
let ME_xslope=((($ME_XAXIS_MAX))-(($ME_XAXIS_MIN)))/($PPL$XLEN)
let ME_yslope=((($YAXIS_MAX))-(($YAXIS_MIN)))/($PPL$YLEN)

let ME_x1=($ME_XAXIS_MIN)+ME_xslope*x1
let ME_x2=($ME_XAXIS_MIN)+ME_xslope*x2
let ME_y1=($YAXIS_MIN)+ME_yslope*y1
let ME_y2=($YAXIS_MIN)+ME_yslope*y2

plot/over/vs/nolab/line=2 {`ME_x1`,`ME_x2`},{`ME_y1`,`ME_y2`}